From f07a4c844da9f0ecae5bbee1ab94be56505f26f7 Mon Sep 17 00:00:00 2001
From: Thomas Bushnell <thomas@gnu.org>
Date: Tue, 25 Feb 1997 21:28:37 +0000
Subject: Initial source

---
 i386/i386at/boothdr.S | 62 +++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 62 insertions(+)
 create mode 100644 i386/i386at/boothdr.S

(limited to 'i386/i386at/boothdr.S')

diff --git a/i386/i386at/boothdr.S b/i386/i386at/boothdr.S
new file mode 100644
index 0000000..de80753
--- /dev/null
+++ b/i386/i386at/boothdr.S
@@ -0,0 +1,62 @@
+
+#include <mach/machine/asm.h>
+
+#include "i386asm.h"
+
+	.text
+
+	/* We should never be entered this way.  */
+	.globl	start,_start
+start:
+_start:
+	jmp	boot_entry
+
+	/* MultiBoot header - see multiboot.h.  */
+#define	MULTIBOOT_MAGIC		0x1BADB002
+#ifdef __ELF__
+#define MULTIBOOT_FLAGS		0x00000002
+#else  /* __ELF__ */
+#define MULTIBOOT_FLAGS		0x00010002
+#endif /* __ELF__ */
+	P2ALIGN(2)
+boot_hdr:
+	.long	MULTIBOOT_MAGIC
+	.long	MULTIBOOT_FLAGS
+		/*
+		 * The next item here is the checksum.
+		 * XX this works OK until we need at least the 30th bit.
+		 */
+	.long	- (MULTIBOOT_MAGIC+MULTIBOOT_FLAGS)
+#ifndef __ELF__	/* a.out kludge */
+	.long	boot_hdr	/* header_addr */
+	.long	_start		/* load_addr */
+	.long	_edata		/* load_end_addr */
+	.long	_end		/* bss_end_addr */
+	.long	boot_entry	/* entry */
+#endif /* __ELF__ */
+
+boot_entry:
+
+	/* Switch to our own interrupt stack.  */
+	movl	$_intstack+INTSTACK_SIZE,%esp
+
+	/* Reset EFLAGS to a known state.  */
+	pushl	$0
+	popf
+
+	/* Clear uninitialized data.  */
+	lea     _edata,%edi
+	lea     _end,%ecx
+	subl    %edi,%ecx
+	xorl    %eax,%eax
+	rep
+	stosb
+
+	/* Push the boot_info pointer to be the second argument.  */
+	pushl	%ebx
+
+	/* Jump into C code.  */
+	call	EXT(c_boot_entry)
+
+	.comm	_intstack,INTSTACK_SIZE
+
-- 
cgit v1.2.3